Viewing /PKGBUILD.

View raw.

Click here to go back to the Git tree for ueberzug-git.

# Maintainer: exponential <echo ZXhwb25lbnRpYWxtYXRyaXhAcHJvdG9ubWFpbC5jb20K | base64 -d>
# Contributor: mehalter <micah at mehalter.com>
_pkgname=ueberzug
pkgname=${_pkgname}-git
pkgver=18.2.1.r0.g637d7fc
pkgrel=2
pkgdesc="ueberzug is an python script which aims to replace w3mimgdisplay"
arch=('amd64')
url="https://github.com/ueber-devel/${_pkgname}"
license=('GPL3')
depends=("libxext6" "libxres1" "python3-pil" "python3" "python3-docopt" "python3-attr")
makedepends=("git" "python3-setuptools" "python3-dev" "libxext-dev" "libxres-dev")
source=("git+${url}")
b2sums=('SKIP')
conflicts=("${_pkgname}")
provides=("${_pkgname}=${pkgver}")

pkgver() {
  cd "$srcdir/$_pkgname"
  printf "$(git describe --long --always | sed 's/\([^-]*-g\)/r\1/;s/-/./g')" 
}

build() {
  cd "$srcdir/$_pkgname"
  python3 setup.py build
}

package() {
  cd "$srcdir/$_pkgname"
  python3 setup.py install --prefix=/usr --root "${pkgdir}" --optimize=1 --skip-build --install-layout deb
  # bug, remove sources
  rm -Rf "$pkgdir/usr/lib/python3/dist-packages/ueberzug/X"
  install -Dm644 "LICENSE" "$pkgdir/usr/share/doc/$_pkgname/license"
  install -Dm644 "README.md" "$pkgdir/usr/share/doc/$_pkgname/readme"
}