# Maintainer: exponential <echo ZXhwb25lbnRpYWxtYXRyaXhAcHJvdG9ubWFpbC5jb20K | base64 -d>
# Contributor: mehalter (AUR) <micah at mehalter.com>
_pkgname=ueberzug
pkgname=${_pkgname}-git
pkgver=18.3.0.r0.gfcc7cd9
pkgrel=1
pkgdesc="ueberzug is an python script which aims to replace w3mimgdisplay"
arch=('amd64')
url="https://github.com/ueber-devel/${_pkgname}"
license=('GPL3')
depends=("libxext6" "libxres1" "python3-pil" "python3" "python3-docopt" "python3-attr")
makedepends=("git" "python3-mesonpy" "python3-dev" "libxext-dev" "libxres-dev")
source=("git+${url}")
b2sums=('SKIP')
conflicts=("${_pkgname}" "ueberzugpp")
provides=("${_pkgname}=${pkgver}")

pkgver() {
  cd "$srcdir/$_pkgname"
  printf "$(git describe --long --always | sed 's/\([^-]*-g\)/r\1/;s/-/./g')" 
}

build() {
  cd "$srcdir/$_pkgname"
  python3 -m build --no-isolation --wheel
}

package() {
  cd "$srcdir/$_pkgname"
  python3 -m installer --destdir="$pkgdir" dist/*.whl #--optimize=1 --skip-build
  # Manual remove local
  mv "$pkgdir/usr/local/"* "$pkgdir/usr/"
  rmdir "$pkgdir/usr/local"
  # bug, remove sources
  rm -Rf "$pkgdir/usr/lib/python3/dist-packages/ueberzug/X"
  # doc
  install -Dm644 "README.md" "$pkgdir/usr/share/doc/$_pkgname/readme"
  ln -s /usr/share/common-licenses/GPL-3 "$pkgdir/usr/share/doc/$_pkgname/"
}