makedeb


mov-cli 4.3.0-0


Python script for watching movies and TV shows via the terminal.

Viewing /PKGBUILD.

View raw.

Click here to go back to the Git tree for mov-cli.

# Maintainer: exponential <echo ZXhwb25lbnRpYWxtYXRyaXhAcHJvdG9ubWFpbC5jb20K | base64 -d>
pkgname='mov-cli'
pkgver=4.3.0
pkgrel=0
pkgdesc="Python script for watching movies and TV shows via the terminal."
arch=('all')
url="https://github.com/mov-cli/mov-cli"
license=('GPL3')
makedepends=('python3-build' 'python3-setuptools' 'python3-setuptools-scm' 'python3-installer' 'python3-wheel') 
depends=('python3-httpx' 'python3-toml' 'python3-devgoldyutils' 'python3-typer' 'python3-inquirer' 'python3-bs4' 'python3-unidecode' 'python3-deprecation' 'python3-thefuzz' 'mpv')
optdepends=("fzf"
            "python3-lxml: faster scraping" 
            "python3-cssselect: debian bug, required for python3-lxml"
            "vlc: alternate media player"
            "python3-mov-cli-anime: mov-cli v4 plugin for anime"
            "python3-mov-cli-films: mov-cli v4 plugin for films and shows"
            "python3-mov-cli-youtube: mov-cli v4 plugin for youtube"
            "python3-mov-cli-test: mov-cli v4 plugin for free films and animations in the CC")
source=("$pkgname-$pkgver.tar.gz::https://github.com/mov-cli/mov-cli/archive/refs/tags/$pkgver.tar.gz")
b2sums=('da4f8c2f436f4a9cb1176c01b07c2a73832d0e22312df609741f978bc8d3749491441638de544c7ae233879267d359490838aab9b0cc79ec03eaf16e7601c3c5')

prepare() {
  echo "Disclaimer: This project is to be used at the user's own risk, based on their government and laws."
}

build(){
  cd "$srcdir/$pkgname-$pkgver"
  python3 -m build --no-isolation --wheel
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  python3 -m installer --destdir="$pkgdir" dist/*.whl #--optimize=1 --skip-build
  # Manual remove local
  mv "$pkgdir/usr/local/"* "$pkgdir/usr/"
  rmdir "$pkgdir/usr/local" 
  # doc
  install -Dm644 "README.md" "$pkgdir/usr/share/doc/$pkgname/readme"
  install -Dm644 "disclaimer.md" "$pkgdir/usr/share/doc/$pkgname/disclaimer"
  ln -s /usr/share/common-licenses/GPL-3 "$pkgdir/usr/share/doc/$pkgname/"
}