# Maintainer: exponential <echo ZXhwb25lbnRpYWxtYXRyaXhAcHJvdG9ubWFpbC5jb20K | base64 -d>
pkgname='mov-cli'
pkgver=4.4.15
pkgrel=0
pkgdesc="Python script for watching movies and TV shows via the terminal."
arch=('all')
url="https://github.com/mov-cli/mov-cli"
license=('MIT')
makedepends=('python3-build' 'python3-installer' 'python3-wheel') 
depends=('python3-httpx' 'python3-toml' 'python3-devgoldyutils' 'python3-typer' 'python3-inquirer' 'python3-bs4' 'python3-unidecode' 'python3-deprecation' 'python3-thefuzz' 'python3-decouple' 'mpv')
optdepends=("fzf"
            "python3-lxml: faster scraping" 
            "python3-cssselect: debian bug, required for python3-lxml"
            "python3-levenshtein: faster SequenceMatcher"
            "vlc: alternate media player"
            "python3-mov-cli-otaku-watcher: mov-cli v4 plugin for anime"
            "python3-mov-cli-film-central: mov-cli v4 plugin for films and shows"
            "python3-mov-cli-youtube: mov-cli v4 plugin for youtube"
            "python3-mov-cli-test: mov-cli v4 plugin for free films and animations in the CC")
source=("$pkgname-$pkgver.tar.gz::https://github.com/mov-cli/mov-cli/archive/refs/tags/$pkgver.tar.gz")
b2sums=('7bbc0a868b3be0795e19a304c83246fe17874b6e431b0c8e86d130b3cd7881393ab4716678a9e330a2696f3489a66b559b6a34288eee1bddc326e0e7dde97f96')

prepare() {
  echo "Disclaimer: This project is to be used at the user's own risk, based on their government and laws."
}

build(){
  cd "$srcdir/$pkgname-$pkgver"
  python3 -m build --no-isolation --wheel
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  python3 -m installer --destdir="$pkgdir" dist/*.whl #--optimize=1 --skip-build
  # Manual remove local
  mv "$pkgdir/usr/local/"* "$pkgdir/usr/"
  rmdir "$pkgdir/usr/local" 
  # doc
  install -Dm644 "README.md" "$pkgdir/usr/share/doc/$pkgname/readme"
  install -Dm644 "disclaimer.md" "$pkgdir/usr/share/doc/$pkgname/disclaimer"
  install -Dm644 "LICENSE" "$pkgdir/usr/share/doc/$pkgname/license"
}