Viewing /PKGBUILD.

View raw.

Click here to go back to the Git tree for zelda-classic-bin.

# Maintainer: exponential <echo ZXhwb25lbnRpYWxtYXRyaXhAcHJvdG9ubWFpbC5jb20K | base64 -d>
# Contributor: Marcell Meszaros (AUR) < marcell.meszaros AT runbox.eu >
# Contributor: carstene1ns (AUR) <arch carsten-teibes de> - http://git.io/ctPKG

# multiarch and bug workaround
# read instructions README.pkg or /usr/share/doc/zelda-classic/README.pkg

# for makedeb multiarch,
# starting with version 16 use this:
# export MAKEDEB_DPKG_ARCHITECTURE='i386'
# in the SHELL, **NOT** in the PKGBUILD, or it will throw a fatal error.

_pkgname=zelda-classic
pkgname=zelda-classic-bin
pkgver=2.50.2.29
pkgrel=0
pkgdesc="A tribute to Nintendo's The Legend of Zelda (NES), read install instructions in README.pkg"
arch=('i386')
url="http://zeldaclassic.com"
license=('GPL3' 'custom')
depends=('libxxf86vm1' 'libxcursor1' 'libasound2-plugins')
optdepends=('libgtk2.0-0:            needed by the launcher'
            'gtk2-engines-murrine:   optional for the launcher'
            'gtk2-engines-pixbuf:    optional for the launcher'
            'libcanberra-gtk-module: optional for the launcher'
            'libatk-adaptor:         optional for the launcher'
            #'xserver-xephyr: serious Xorg bug workaround, install native package'
)
provides=('zelda-classic')
conflicts=('zelda-classic')
source=("$_pkgname-2-50-2-linux.tar.gz::https://www.zeldaclassic.com/download/100/"
        "$_pkgname.png"
        "$_pkgname-zlaunch.png"
        "$_pkgname-zquest.png"
        "$_pkgname.desktop"
        "$_pkgname-zlaunch.desktop"
        "$_pkgname-zquest.desktop"
        "$_pkgname.sh"
        "$_pkgname-workaround.sh"
        "$_pkgname-README.pkg")
b2sums=('fb8b8f672e277ebd13e59c47064dbc3dcfdcc7fd8d26256258c3177a836dc2cee87d62b99446f13a610e7581bf3b5d716e4e66d944460341a3c770efa64ca811'
        'f3514a8f9911c2955955ab4af60e364c6dcafdc727f1da8f73ed3f52501cc6b23fdb98a2c9ba8139b77a984312d99270556d8e68ac4a36913cf48557f0b4ceb9'
        '11a6698d7905490742538d48e34be7151a69de8050f9431f69e610e41de56876316daa29fb1700599579641a3b013b3d028a3181aad79759fd99e3f3e302480b'
        'a4d5f37f869626fb350bf9c7f3ce84ac201b8120ab0c363eccd6588fa7b8a0a310958dcc5db86909527791563751491359a38d80095a02745132770e8f0a9005'
        'c991b7c6b85c1288fa1c624f9530ae5a45ca3154f823b5dc91cc3ea136eaeaae00e399076296d4b6789459efba3e2e84e840b229d35538d400e7e11d87e458c8'
        'c9e579e7e36ef1bf9e2dab19c11bc3c0da0c427a45f0b8f1db8e11c8d4e2b0897d540506f8727ab6006ee8947d9df0035afcca83a23ac8d0fed437be492943b7'
        '954eb03b87ae1382a5e609813755823f905341f35636a1eb67c19a8fd498d743f5aa797428efcee27fce29b7eb491495a32280a14b7b2252dfc38c4486b2ac23'
        '1a3693d094d0c2289ef9c0776c0f5a5ab80c85364b56fa504c416b5f5e063215800fd2d587df5ae0bb43acc7c6bdbbbe97bc34fe91a05075cec1c7e6f02f7162'
        '3c2c1dc85120a340b29f0288426ed4d86ef06acaa4fd86d141bcc223071f0449858a3320e0d070ab9c860a16ea78cb1a3c3e0fd4ad5fe1642cb013d213d77903'
        '512926d10029a688e3328fc5a4992da643864f9eddc3944ee7eb708d1461054c84c61139246809a3b4a790cdb65fd62367778284c37552de3565d70e5aeadb4d')
options=('!strip')

package() {
  cd "Zelda Classic"

  # create folders
  install -d "$pkgdir"/{usr/games,usr/{share/{doc/$_pkgname,games/$_pkgname/samplesoundset},libexec/$_pkgname,lib/$_pkgname}}

  # install binaries + libraries
  install -m755 {romview,zelda,zlaunch,zquest}-l "$pkgdir"/usr/libexec/$_pkgname
  install -m644 *.so "$pkgdir"/usr/lib/$_pkgname

  # Xorg bug workaround
  mv "$pkgdir"/usr/libexec/$_pkgname/zelda-l "$pkgdir"/usr/libexec/$_pkgname/zelda-l.real
  install -m755 ../$_pkgname-workaround.sh "$pkgdir"/usr/libexec/$_pkgname/zelda-l 

  # install data files
  install -m644 samplesoundset/patches.dat "$pkgdir"/usr/share/games/$_pkgname/samplesoundset
  install -m644 *.{qst,dat,nsf} "$pkgdir"/usr/share/games/$_pkgname

  # install doc files
  install -m644 *.{txt,zh} "$pkgdir"/usr/share/doc/$_pkgname
  install -m644 ../$_pkgname-README.pkg "$pkgdir"/usr/share/doc/$_pkgname/README.pkg

  # install launchers
  install -m755 ../$_pkgname.sh "$pkgdir"/usr/games/$_pkgname
  ln -s $_pkgname "$pkgdir"/usr/games/$_pkgname-zlaunch
  ln -s $_pkgname "$pkgdir"/usr/games/$_pkgname-zquest

  # install icon and desktop files
  for i in $_pkgname{,-zlaunch,-zquest}; do
    install -Dm644 ../$i.png "$pkgdir"/usr/share/pixmaps/$i.png
    install -Dm644 ../$i.desktop "$pkgdir"/usr/share/applications/$i.desktop
  done

  # install soundset licence
  install -Dm644 samplesoundset/COPYRIGHT "$pkgdir"/usr/share/doc/$_pkgname/LICENSE-soundset
}