Viewing /PKGBUILD.

View raw.

Click here to go back to the Git tree for yumenikki-en.

# Maintainer: exponential <echo ZXhwb25lbnRpYWxtYXRyaXhAcHJvdG9ubWFpbC5jb20K | base64 -d>
# Contributor: maz-1 (AUR) <ohmygod19993 at gmail dot com>

_pkgname=yumenikki
pkgname="${_pkgname}-en"
pkgver=0.10
pkgrel=1
pkgdesc="Surrealistic adventure game about exploring the dreams, aka \"Dream Diary\", English Ver."
url='http://www3.nns.ne.jp/pri/tk-mto/'
arch=('all')
license=('freeware')
# rpg2003-rtp
depends=('easyrpg-player')
optdepends=('easyrpg-repo')
# Alternate links: http://www.theneitherworld.com/yumenikki/links.htm
#makedepends=('curl')
# curl http://www.mediafire.com/download/98jpx2dm3f2te0h/Yume_Nikki.rar | grep -oP 'http://download\d{4}.mediafire.com/\S+/Yume_Nikki.rar'
source=("yumenikki-en.7z::https://dl.dropbox.com/s/a5dqfazyfrvjr8f/yumenikki-en.7z?dl=1"
        "${pkgname}.desktop"
        "${pkgname}.png"
        "${pkgname}.sh")
b2sums=('8c458f9b387edf6e4bf4d4fd81b6acec565b553c8393b616d36915f2c6cd9e70c9ae125d3a65886a4852fd890dc8e8b66114fc1bdb0171742812286d6d7e5cbd'
        'cf5248b05e1aa4f78fd4e024cb8e1debda41619524422539e9a8435ee1a20a05dd362da4a1a7bbd522202f60c29312b324e9431d195e10a61cf618b2b2621b5e'
        '08bf62cc971ca2deb8d05ace2e0b03866d6f8996d76ad38a65177f0640ab7166dc29c21521efb0dbcbea8f865eb611009f7ff54635e0b4d4332f98d0900b1b86'
        'ec3892fd2e8386e160869b2245b0e52a3ea62520f2d07beb3b1421655f860f7c438803a10a77308992ef3fe6375cfa673a585e2cbba2bfbefd48e1041fb51b8b')
options=('!strip')

prepare() {
  cd "${srcdir}/${pkgname}"
  # Clean up
  rm *.exe
}
         
package() {
  cd "${srcdir}/${pkgname}"  
  # Folders
  install -dm755 "${pkgdir}/usr/"{games,share/{applications,"doc/${pkgname}",games,icons/hicolor/128x128/apps}}
  # Script
  install -Dm755 "${srcdir}/${pkgname}.sh" "${pkgdir}/usr/games/${pkgname}"
  # Install data
  cp -R "${srcdir}/${pkgname}" "${pkgdir}/usr/share/games/"
  # bug: fix permissions, can't chmod the extracted files directly. 
  chmod -R u=rw,go=r,a+X "${pkgdir}/usr/share/games"
  # doc
  mv "${pkgdir}/usr/share/games/${pkgname}/readme.txt" "${pkgdir}/usr/share/doc/${pkgname}/readme"
  # Icon and desktop file
  install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
  install -Dm644 "${srcdir}/${pkgname}.png" "${pkgdir}/usr/share/icons/hicolor/128x128/apps/${pkgname}.png"
}