Viewing /PKGBUILD.

View raw.

Click here to go back to the Git tree for viu-git.

# Maintainer: John Ruschmeyer <jruschme@gmail.com>
# Contributor: orhun <orhunparmaksiz@gmail.com>
# https://github.com/orhun/pkgbuilds

pkgname=viu-git
pkgver=1.4.0.r6.ga6ff231
pkgrel=1
pkgdesc="Simple terminal image viewer (git)"
arch=('amd64')
url="https://github.com/atanunq/viu"
license=('MIT')
depends=()
makedepends=('rustc')
conflicts=("${pkgname%-git}")
provides=("${pkgname%-git}")
source=("git+${url}")
sha512sums=('SKIP')

pkgver() {
  cd ../"${pkgname%-git}"
  (git fetch --unshallow || get fetch --all)
  git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "${pkgname%-git}"
  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}

build() {
  cd "${pkgname%-git}"
  cargo build --frozen --release
}

check() {
  cd "${pkgname%-git}"
  cargo test --frozen
}

package() {
  cd "${pkgname%-git}"
  install -Dm 755 "target/release/${pkgname%-git}" -t "${pkgdir}/usr/bin"
  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  install -Dm 644 LICENSE-MIT -t "$pkgdir/usr/share/licenses/$pkgname"
}