Viewing /PKGBUILD.

View raw.

Click here to go back to the Git tree for scrcpy.

# Maintainer: Chris Dunder <cdunder@gmail.com>
# Contributor: Andrew Rabert <ar@nullsum.net>

pkgname='scrcpy'
_gitname='scrcpy'
provides=('scrcpy')
pkgver='1.24'
pkgrel='1'
pkgdesc='Display and control your Android device'
arch=('i686' 'x86_64')
url='https://github.com/Genymobile/scrcpy'
license=('Apache')
depends=('adb' 'ffmpeg' 'libsdl2-2.0-0' 'libusb-1.0-0')
makedepends=('gcc' 'git' 'pkg-config' 'meson' 'ninja-build' 'libsdl2-dev' 'libavcodec-dev' 'libavdevice-dev' 'libavformat-dev' 'libavutil-dev' 'libusb-1.0-0-dev')
source=("git+${url}.git#tag=v${pkgver}"
        "${url}/releases/download/v${pkgver}/scrcpy-server-v${pkgver}")
conflicts=("${_gitname}-git" "${_gitname}-bin")
sha256sums=('SKIP'
            'ae74a81ea79c0dc7250e586627c278c0a9a8c5de46c9fb5c38c167fb1a36f056')

build() {
    cd "${srcdir}/${_gitname}"
    meson \
        --prefix /usr \
        --buildtype release \
        --strip \
        -Db_lto=true \
        -Dprebuilt_server="../scrcpy-server-v${pkgver}" \
        build
    ninja -C build
}

package() {
    cd "${srcdir}/${_gitname}"
    DESTDIR="${pkgdir}" ninja -C build install
}