Viewing /PKGBUILD.

View raw.

Click here to go back to the Git tree for radiotray-ng.

# Maintainer: John Ruschmeyer <jruschme@gmail.com>
# Contributor: twa022 <twa022 at gmail dot com>

pkgname=radiotray-ng
pkgver=0.2.8
pkgrel=3
pkgdesc="An Internet radio player for Linux"
arch=('i386' 'amd64')
url="https://github.com/ebruck/radiotray-ng"
license=('GPL')
depends=('curl' 'libgstreamer1.0-0' 'gstreamer1.0-plugins-good'
	'libayatana-appindicator3-1' 'libbsd0' 'libnotify4' 'libxdg-basedir1'
	'libglibmm-2.4-1v5' 'libwxgtk3.0-gtk3-0v5'
	'libboost-log1.74.0' 'libboost-program-options1.74.0' 'libjsoncpp24')
focal_depends=('curl' 'libgstreamer1.0-0' 'gstreamer1.0-plugins-good'
	'libayatana-appindicator3-1' 'libbsd0' 'libnotify4' 'libxdg-basedir1'
	'libglibmm-2.4-1v5' 'libwxgtk3.0-gtk3-0v5'
	'libboost-log1.71.0' 'libboost-program-options1.71.0' 'libjsoncpp1')
makedepends=('cmake' 'libcurl4-openssl-dev' 'lsb-release' 'libjsoncpp-dev' 'libgstreamer1.0-dev'
	'libayatana-appindicator3-dev' 'libbsd-dev' 'libnotify-dev'
	'libxdg-basedir-dev' 'libglibmm-2.4-dev' 'libwxgtk3.0-gtk3-dev'
	'libboost-log-dev' 'libboost-program-options-dev')
optdepends=('python3-lxml: Convert radiotray bookmarks to radiotray-ng format')
options=('!libtool')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/ebruck/radiotray-ng/archive/v${pkgver}.tar.gz")
sha256sums=('5bc256c21c88d055d42ed44915e3d16642004327bf45597b9c7278c88b28a5cb')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  sed -i 's:-Werror::' CMakeLists.txt
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  [ -d build ] && rm -r build
  mkdir build
  cd build

  cmake .. -DCMAKE_BUILD_TYPE=Release \
    -DBUILD_TESTS=no
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}/build"
  make DESTDIR="$pkgdir" install
}