Viewing /PKGBUILD.

View raw.

Click here to go back to the Git tree for principia-git.

# Maintainer: ROllerozxa <rollerozxa@voxelmanip.se>
pkgname=principia-git
pkgver=1.5.2.r1.b41feea
pkgrel=1
pkgdesc="Physics-based sandbox building game."
url='https://github.com/Bithack/principia/'
arch=('amd64' 'i686')
license=('bsd-3')
depends=(
	'libsdl2-2.0-0' 'libsdl2-gfx-1.0-0' 'libsdl2-image-2.0-0' 'libsdl2-mixer-2.0-0' 'libsdl2-ttf-2.0-0'
	'libgtk2.0-0' 'libcurl3-gnutls' 'libpng16-16' 'libjpeg62-turbo' 'libfreetype6')
makedepends=(
	'libsdl2-dev' 'libsdl2-gfx-dev' 'libsdl2-image-dev' 'libsdl2-mixer-dev' 'libsdl2-ttf-dev'
	'libgtk2.0-dev' 'libcurl4-openssl-dev' 'libpng-dev' 'libjpeg-dev' 'libfreetype6-dev'
	'automake')
source=('git+https://github.com/Bithack/principia')
sha256sums=(SKIP)
options=()

pkgver() {
	cd principia
	printf "1.5.2.beta.r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd principia/build-linux
	./autogen.sh
	./configure
	./go --clean --release --silent
}

package() {
	cd principia/build-linux
	install -Dm755 "apparatus2" "${pkgdir}/opt/principia/principia"
	install -d "${pkgdir}/usr/bin/"
	ln -s /opt/principia/principia "${pkgdir}/usr/bin/"
	
	install -Dm644 "principia.desktop" "${pkgdir}/usr/share/applications/principia.desktop"
	install -Dm644 "principia-url-handler.desktop" "${pkgdir}/usr/share/applications/principia-url-handler.desktop"
	
	install -Dm644 "principia.png" "${pkgdir}/usr/share/pixmaps/principia.png"

	install -d "${pkgdir}/opt"
	cp -r ../data-{shared,pc} "${pkgdir}/opt/principia/"
}