Viewing /PKGBUILD.

View raw.

Click here to go back to the Git tree for ogre.

# Maintainer: Edgar <Edgar{at}AnotherFoxGuy.com>

pkgname=ogre
pkgver=14.1.2
pkgrel=1
pkgdesc='Scene-oriented, flexible 3D engine written in C++'
arch=('i686' 'amd64')
url='https://www.ogre3d.org'
license=('custom:MIT')
depends=('libfreeimage-dev' 'libfreetype6-dev' 'libzzip-dev' 'libois-dev'
    'nvidia-cg-toolkit' 'libzzip-dev' 'libtinyxml-dev' 'libxrandr-dev'
    'libgles2-mesa-dev' 'libxt-dev' 'libxaw7-dev' 'libglu1-mesa-dev')
makedepends=('cmake')
provides=('ogre=14.1.2')
source=("https://github.com/OGRECave/ogre/archive/v${pkgver}.tar.gz")
sha256sums=('7269d659fa74b61b5df48aa81aa9a517227cb7da9f316f04cb9093f963e6911c')

prepare() {
    mkdir -p ogre-${pkgver}/build
}

build() {
    cd ogre-${pkgver}/build

    cmake .. \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DOGRE_BUILD_DEPENDENCIES=FALSE \
        -DCMAKE_BUILD_TYPE=Release \
        -DOGRE_BUILD_PLUGIN_FREEIMAGE=TRUE \
        -DOGRE_BUILD_PLUGIN_EXRCODEC=TRUE \
        -DOGRE_NODELESS_POSITIONING=TRUE \
        -DOGRE_BUILD_SAMPLES=FALSE \
        -DOGRE_INSTALL_DOCS=FALSE

    make -j$(nproc)
}

package() {
    cd ogre-${pkgver}/build

    make DESTDIR=${pkgdir} install

    install -Dm644 ../Docs/License.md ${pkgdir}/usr/share/licenses/${pkgname}/license
}