Viewing /PKGBUILD.

View raw.

Click here to go back to the Git tree for nvm.

# Maintainer: exponential <echo ZXhwb25lbnRpYWxtYXRyaXhAcHJvdG9ubWFpbC5jb20K | base64 -d>
# Contributor: Tom Wadley (AUR) <tom@tomwadley.net>
pkgname=nvm
pkgver=0.40.1
pkgrel=0
pkgdesc="Node Version Manager - Simple bash script to manage multiple active node.js versions"
url="https://github.com/nvm-sh/nvm"
arch=('all')
license=('MIT')
optdepends=('bash: bash completion')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/nvm-sh/nvm/archive/v${pkgver}.tar.gz"
        "init-nvm.sh"
        "install-nvm-exec"
        "postinst"
        "postrm")
sha256sums=('b1c750e61acfa6abe9f5ad504ba0e14a7f65c1f3afc69bf0e6051e4358f4a3df'
            '692317bfd036557f59543fef9b67ff38de68208d30361fe385291f58d3ac0425'
            '795d3f6ad3076aa4b0bb9cc48a2e6e79331d121278a887667fb707181a54a10b'
            '105818afb4472ac5118291b16d5a861ccb0e49eca3903bb44114d4cdd2a7f129'
            '76ca1bb86b20a0b5f612d05d7691485991a8a05070c157a7de00a2ca0557258a')

package() {
  cd "${srcdir}"

  # convenience script
  install -Dm644 init-nvm.sh "$pkgdir/usr/share/$pkgname/init-nvm.sh"
  # companion script which installs symlinks in NVM_DIR (see comment in script)
  install -Dm644 install-nvm-exec "$pkgdir/usr/share/$pkgname/install-nvm-exec"
  # postinst/postrm scripts
  install -Dm755 postinst "$pkgdir/DEBIAN/postinst"
  install -Dm755 postrm "$pkgdir/DEBIAN/postrm"

  cd "${pkgname}-${pkgver}"

  # nvm itself
  install -Dm644 nvm.sh "$pkgdir/usr/share/$pkgname/nvm.sh"
  # nvm-exec script for 'nvm exec' command
  install -Dm755 nvm-exec "$pkgdir/usr/share/$pkgname/nvm-exec"
  # bash completion
  install -Dm644 bash_completion "$pkgdir/usr/share/$pkgname/bash_completion"
  # doc
  install -Dm644 LICENSE.md "$pkgdir/usr/share/doc/$pkgname/license"
  install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/readme"
}

# vim:set ts=2 sw=2 et: