Viewing /PKGBUILD.

View raw.

Click here to go back to the Git tree for nsxiv.

# Maintainer:  only_vip <onlyme_vip@protonmail.com>
# thanks to AUR maintianer: Sanjay Pavan <withercubes@protonmail.com>
pkgname=nsxiv
pkgver=31
pkgrel=1
pkgdesc='Neo or New or Not Simple or Small or Suckless X Image Viewer'
arch=('amd64')
license=('GPL2')
url='https://codeberg.org/nsxiv/nsxiv'
depends=('libimlib2' 'desktop-file-utils' 'xdg-utils'  'hicolor-icon-theme')
makedepends=('libimlib2-dev' 'libexif-dev' 'libwebp-dev')
optdepends=('libxft2' 'fontconfig' 'giflib-tools' 'libexif12' 'libwebp6')
source=("${pkgname}-$pkgver.tar.gz"::"https://codeberg.org/nsxiv/nsxiv/archive/v$pkgver.tar.gz")
sha512sums=('64139d3a0c74a96eb01f21689a5d9af64012dd02d85ab6984eb4881218eb095f05134bbd91da5ff6fe8246782121a90f6b3524f5a51296de0dfbe852f600cfaa')
conflicts=('nsxiv')
provides=('nsxiv')

prepare() {
  cd "${srcdir}/${pkgname}"
  [ ! -f config.h ] && cp config.def.h config.h
  sed -i -e '/^install: / s|: all|:|' Makefile
}

build() {
  make -C "${pkgname}"
}

package() {
  cd "${srcdir}/${pkgname}"
  make PREFIX=/usr DESTDIR="${pkgdir}" install-all
}