Viewing /PKGBUILD.

View raw.

Click here to go back to the Git tree for keepassxc.

# Maintainer: hiddeninthesand <hiddeninthesand at pm dot me>

pkgname="keepassxc"
_gitname="keepassxc"
pkgver='2.7.4'
pkgrel='1'
pkgdesc="Cross-platform community-driven port of KeePass Password Safe"
arch=('i686' 'x86_64')
url="https://github.com/keepassxreboot/keepassxc"
license=('GPL2')
depends=('qtbase5-dev' 'qtbase5-private-dev' 'qttools5-dev' 'qttools5-dev-tools' 'libqt5svg5-dev' 'libargon2-dev' 'libminizip-dev' 'libbotan-2-dev' 'libqrencode-dev' 'zlib1g-dev' 'asciidoctor' 'libreadline-dev' 'libpcsclite-dev' 'libusb-1.0-0-dev' 'libxi-dev' 'libxtst-dev' 'libqt5x11extras5-dev')
makedepends=('git' 'build-essential' 'cmake' 'g++')
provides=("keepassxc=$pkgver")
replaces=('keepassx-http' 'keepassx-reboot-git')
options=(!emptydirs)
source=("git+https://github.com/keepassxreboot/keepassxc.git#tag=${pkgver}")
sha256sums=('SKIP')
conflicts=("${_gitname}-git" "${_gitname}-bin")

build() {
    cd "${_gitname}"
    cmake -B build \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_INSTALL_BINDIR=/usr/bin \
        -DCMAKE_INSTALL_LIBDIR=/usr/lib \
        -DCMAKE_VERBOSE_MAKEFILE=OFF \
        -DWITH_GUI_TESTS=ON \
        -DWITH_XC_ALL=ON \
        -DWITH_XC_KEESHARE_SECURE=ON \
        -DCMAKE_BUILD_TYPE=RelWithDebInfo
    make -C build
}

#check() {
#    cd "${_gitname}/build"
#    xvfb-run --auto-display make test
#}

package() {
    cd "${_gitname}/build"
    make DESTDIR="${pkgdir}" install
}