Viewing /PKGBUILD.

View raw.

Click here to go back to the Git tree for gridwars-git.

# Maintainer: exponential <echo ZXhwb25lbnRpYWxtYXRyaXhAcHJvdG9ubWFpbC5jb20K | base64 -d>
# Contributor: trap000d (AUR) <trap000d at gmail dot com>

pkgname=gridwars-git
pkgver=1.r1.e760698
pkgrel=1
pkgdesc="Grid Wars 2: A clone of Geometry Wars"
_srcname="GridWars"
arch=('amd64')
url="https://github.com/mmatyas/GridWars"
license=('freeware')
depends=('libglvnd0' 'libxdmcp6' 'libxxf86vm1' 'libxau6' 'libxft2' 'libx11-6' 'libglu1-mesa')
makedepends=('bmx-ng-bin-0.129.3.45' 'git' 'libasound2-dev' 'libpulse-dev' 'libxft-dev' 'libxxf86vm-dev')
source=("git+https://github.com/mmatyas/GridWars.git")
sha256sums=('SKIP')

pkgver() {
    cd ${srcdir}/${_srcname}
    printf "1.r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd ${srcdir}/${_srcname}
    # if using firejail, add these in makedeb.local
    #ignore noexec ${HOME}
    #ignore memory-deny-write-execute
    bmk makeapp -t gui -r -w gridwars.bmx
}

package() {

    #Creating Directories
    install -m755 -d $pkgdir/usr/{games,libexec/gridwars,share/{applications,doc/gridwars,pixmaps,games/gridwars/{gfx/{high,med,low,solid,user},music,sounds}}}

    # Installing
    install -D -m755 $srcdir/${_srcname}/gridwars $pkgdir/usr/libexec/gridwars/
    install -D -m644 $srcdir/${_srcname}/gfx/colourpick.png $pkgdir/usr/share/games/gridwars/gfx/colourpick.png
    for i in high low med solid user; do
        install -D -m644 $srcdir/${_srcname}/gfx/$i/* $pkgdir/usr/share/games/gridwars/gfx/$i
    done
    install -D -m644 $srcdir/${_srcname}/music/* $pkgdir/usr/share/games/gridwars/music/
    install -D -m644 $srcdir/${_srcname}/sounds/* $pkgdir/usr/share/games/gridwars/sounds/

    install -D -m644 $srcdir/${_srcname}/Readme.txt $pkgdir/usr/share/doc/gridwars/readme
    install -D -m644 $srcdir/${_srcname}/README.md $pkgdir/usr/share/doc/gridwars/readme2

    # Desktop file
echo "[Desktop Entry]
Type=Application
Version=1.0
Encoding=UTF-8
Name=GridWars 2
Name[en]=GridWars 2
Name[fr]=GridWars 2
GenericName=A Geometry Wars clone
GenericName[en]=A Geometry Wars clone
GenericName[fr]=Un clone de Geometry Wars
Comment=A shoot-them-up taking place on a magnetic grid where you must survive to enemies waves.
Comment[en]=A shoot-them-up taking place on a magnetic grid where you must survive to enemies waves.
Comment[fr]=Un shoot-them-up prenant place sur une grille magnétique ou vous devez survivre à de multiples vagues d'ennemies.
Icon=gridwars
Exec=gridwars
Terminal=false
StartupNotify=false
Categories=Application;Game;ArcadeGame" > $pkgdir/usr/share/applications/gridwars.desktop

    install -D -m644 $srcdir/${_srcname}/gfx/high/whiteplayer.png $pkgdir/usr/share/pixmaps/gridwars.png

    # Linking binary and stuff 
    ln -sf /usr/share/games/gridwars/gfx $pkgdir/usr/libexec/gridwars/gfx 
    ln -sf /usr/share/games/gridwars/music $pkgdir/usr/libexec/gridwars/music
    ln -sf /usr/share/games/gridwars/sounds $pkgdir/usr/libexec/gridwars/sounds
    ln -sf /usr/libexec/gridwars/gridwars $pkgdir/usr/games/gridwars
}