Viewing /PKGBUILD.

View raw.

Click here to go back to the Git tree for gradience.

pkgname=gradience
_pkgname=Gradience
pkgver=0.3.2
pkgrel=2
pkgdesc="Change the look of Adwaita, with ease"
arch=('any')
url="https://github.com/GradienceTeam/Gradience"
license=('GPL3')
depends=('libadwaita' 'libsoup3' 'python-gobject' 'python-anyascii' 'python-lxml' 'python-pillow' 'python-pluggy' 'python-svglib' 'python-yapsy' 'python-regex' 'python-material-color-utilities' 'libportal-gtk4' 'python-cssutils' 'python-jinja')
makedepends=('meson' 'blueprint-compiler' 'gobject-introspection' 'sassc')
checkdepends=('appstream-glib')
optdepends=('adw-gtk3: The theme from libadwaita ported to GTK-3'
            'adw-gtk-theme: LibAdwaita Theme for all GTK3 and GTK4 Apps.')
install='xdg-config.install'
source=($url/archive/$pkgver.tar.gz)
b2sums=('004e8e93e90a170512d79882890489bf54f8a2f60392758d88b51acbe7249b331b22124a4f171e8fe175ab732a2f63e691d4283e713caf73644d28739108007a')

build() {
  arch-meson "$_pkgname-$pkgver" build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs || :
}

package() {
  meson install -C build --destdir "$pkgdir"
}