Viewing /PKGBUILD.

View raw.

Click here to go back to the Git tree for arch-wiki-lite.

# Maintainer: exponential <echo ZXhwb25lbnRpYWxtYXRyaXhAcHJvdG9ubWFpbC5jb20K | base64 -d>
# Contributor: George Rawlinson (ARCH) <grawlinson@archlinux.org>
# Contributor: Kyle Keen (ARCH) <keenerd@gmail.com>
pkgname=arch-wiki-lite
pkgver=20230228
pkgrel=1
pkgdesc='The Arch Wiki easily searched and viewable on console and browser.'
arch=('all')
url='https://gitlab.archlinux.org/grawlinson/arch-wiki-lite'
license=('GPL2' 'FDL')
depends=('bash' 'gzip')
makedepends=('python3' 'arch-wiki-docs')
optdepends=('dialog: for interactive menu'
            'arch-wiki-docs: for wiki-search-html'
            'xdg-utils: for wiki-search-html')
# update commits from here
# https://gitlab.archlinux.org/archlinux/packaging/packages/arch-wiki-lite/-/raw/main/PKGBUILD
_commit='a9673ee216ba152377543339e1b26e024975d804'
source=("$pkgname-$_commit.zip::$url/-/archive/$_commit/arch-wiki-lite-$_commit.zip")
b2sums=('fc7c6185e37c06ba66ec16c8fe39e5186c7542aa12f8ec58b881051b7dfe95e86526ea09e91d814a9dfbd05f841a9574fe5c466891080a9b0e184a552860f92c')

build() {
  cd "$pkgname-$_commit"
  LC_ALL=en_US.UTF-8 python3 wiki_lite.py
}

package() {
  cd "$pkgname-$_commit"
  # cli scripts
  install -vDm755 -t "$pkgdir/usr/bin" wiki-search{,-html}
  # assets
  install -vd "$pkgdir/usr/share/doc/arch-wiki/text"
  cp -vr wiki/* "$pkgdir/usr/share/doc/arch-wiki/text"
  # dialog
  install -vDm644 -t "$pkgdir/etc/dialog.d" wiki-search.dialog.rc
}