Viewing /PKGBUILD.

View raw.

Click here to go back to the Git tree for android-studio.

# Contributor:  danyf90 <daniele.formichelli@gmail.com>
# Contributor: Philipp 'TamCore' B. <philipp [at] tamcore [dot] eu>
# Contributor: Jakub Schmidtke <sjakub-at-gmail-dot-com>
# Contributor: Christoph Brill <egore911-at-gmail-dot-com>
# Contributor: Lubomir 'Kuci' Kucera <kuci24-at-gmail-dot-com>
# Contributor: Tad Fisher <tadfisher at gmail dot com>
# Contributor: Philippe Hürlimann <p@hurlimann.org>
# Contributor: Kordian Bruck <k@bruck.me>
# Maintainer: theglitchh <souravgope765@gmail.com>
# Maintainer: hiddeninthesand <hiddeninthesand at pm dot me>


pkgname="android-studio"
pkgver='2021.2.1.15'
pkgrel='1'
_build="202.7486908"
pkgdesc="The official Android IDE (Stable branch)"
arch=('i686' 'x86_64')
url="https://developer.android.com/"
license=('APACHE')
makedepends=()
depends=('libasound2' 'freetype2-demos' 'libxrender-dev' 'libxtst6')
optdepends=('gtk2: GTK+ look and feel'
            'libGL: emulator support')
options=('!strip')
source=("https://dl.google.com/dl/android/studio/ide-zips/${pkgver}/android-studio-${pkgver}-linux.tar.gz"
        "${pkgname}.desktop"
        "license.html")
sha256sums=('0018e0dfc0dd2921700516f7a2c443377c557788da7fb0a45243ecb4300745be'
            '73cd2dde1d0f99aaba5baad1e2b91c834edd5db3c817f6fb78868d102360d3c4'
            '9a7563f7fb88c9a83df6cee9731660dc73a039ab594747e9e774916275b2e23e')

if [ "${CARCH}" = "i686" ]; then
    depends+=('java-environment')
fi

package() {
  cd "${srcdir}/${pkgname}"

  # Install the application
  install -d ${pkgdir}/{opt/${pkgname},usr/bin}
  cp -a "bin" "lib" "jre" "plugins" "license" "LICENSE.txt" "build.txt" "product-info.json" "${pkgdir}/opt/${pkgname}"
  ln -s "/opt/android-studio/bin/studio.sh" "${pkgdir}/usr/bin/${pkgname}"

  # Copy licenses
  install -Dm644 "LICENSE.txt" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
  install -Dm644 "${srcdir}/license.html" "${pkgdir}/usr/share/licenses/${pkgname}/license.html"

  # Add the icon and desktop file
  install -Dm644 "bin/studio.png" "${pkgdir}/usr/share/pixmaps/$pkgname.png"
  install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"

  chmod -R ugo+rX "${pkgdir}/opt"
}