# Maintainer: XIVLauncher Linux Maintainers <franz@goat.place>
pkgname=xivlauncher-git
pkgver=1.0.8.0.r1.072480e
pkgrel=1
#epoch=2
pkgdesc="Custom Launcher for Final Fantasy XIV Online (Crossplatform rewrite)"
arch=('amd64')
url='https://github.com/goatcorp/XIVLauncher.Core'
license=('GPL')
depends=(
    'build-essential'
    'aria2'
    'libsdl2-2.0-0'
    'libsecret-1-0'
    'attr'
    'fontconfig'
    'liblcms2-2'
    'libxml2'
    'libxcursor1'
    'libxrandr2'
    'libxdamage1'
    'gettext'
    'libfreetype6'
    'libglu1-mesa'
    'libsm6'
    'libpcap0.8'
    'libfaudio0'
    'desktop-file-utils'
    'libjxr0'
    'xdg-utils'
)
makedepends_x86_64=('dotnet-sdk-6.0')
optdepends=('steam')
options=('!strip')
extensions=()
provides=("xivlauncher=${pkgver}")
conflicts=(
    "xivlauncher"
    "xivlauncher-rb"
)
source=(
    "XIVLauncher.Core::git+https://github.com/goatcorp/XIVLauncher.Core.git"
    "XIVLauncher.desktop"
    "openssl_fix.cnf"
    "xivlauncher-core"
)
sha512sums=(
    'SKIP'
    'c06130b67efff8aa53760cb9c8bd764d4307624ec42c52d58cce388863e64788821f6f836857f200452e75de3b5311466074c70b81ad6d70ab60b286ddfda2e8'
    'c702d45b607a54716ae3f1c9b0aa548b3226da76b0ae4b8a88e49d16e5117a7ff5164e7dd5b6a2799a16a18d53b2de55a26a87888054c25152df5c4824b38fe0'
    'dad16da8e1d2bc772f7e1be1f59fd799c596fa88fb77a7e58a94baf10a1ca2f0ad7e79ad3baa8ba24e35dd0bc748884c74371c447816b1ea61098f58a130313a'
)

pkgver() {
    cd "${srcdir}/XIVLauncher.Core"
    printf "%s.r%s.%s" "$(sed -n 's:.*<Version>\(.*\)</Version>.*:\1:p' src/XIVLauncher.Core/XIVLauncher.Core.csproj)" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
    #git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    mkdir -p "${srcdir}/build"
    cd "${srcdir}/XIVLauncher.Core"
    git submodule update --init --recursive
    cd "${srcdir}/XIVLauncher.Core/src/XIVLauncher.Core/"
    dotnet publish -r linux-x64 --sc -o "${srcdir}/build" --configuration Release
}

package() {
    install -d "${pkgdir}/usr/bin/"
    install -d "${pkgdir}/opt/XIVLauncher/"
    install -D -m644 "${srcdir}/XIVLauncher.desktop" "${pkgdir}/usr/share/applications/XIVLauncher.desktop"
    install -D -m644 "${srcdir}/XIVLauncher.Core/misc/linux_distrib/512.png" "${pkgdir}/usr/share/pixmaps/xivlauncher.png"
    install -D -m644 "${srcdir}/openssl_fix.cnf" "${pkgdir}/opt/XIVLauncher/openssl_fix.cnf"
    cp -r "${srcdir}/build/." "${pkgdir}/opt/XIVLauncher/"
    ln -s "/opt/XIVLauncher/XIVLauncher.Core" "${pkgdir}/usr/bin/XIVLauncher.Core"
    install -D -m755  "${srcdir}/xivlauncher-core" "${pkgdir}/usr/bin/xivlauncher-core"
}