# Maintainer: hifinerd <hifinerd#1365 on Discord>
_pkgname=swayfx
pkgname="$_pkgname"
pkgver=0.2
pkgrel=2
license=("MIT")
pkgdesc="SwayFX: Sway, but with eye candy!"
makedepends=(
	"git"
	"cmake"
	"meson"
	"scdoc"
	"wayland-protocols"
	"libjson-c-dev"
)
depends=(
	"libgl1-mesa-dri"
    "swaybg"
    "polkitd"
    "libc6"
    "libcairo2"
    "libcairo2-dev"
    "libevdev2"
    "libgdk-pixbuf-2.0-0"
    "libgles2"
    "libglib2.0-0"
    "libinput10"
    "libjson-c5"
    "libpango-1.0-0"
    "libpangocairo-1.0-0"
    "libcogl-pango-dev"
    "libpcre2-8-0"
    "libpixman-1-0"
    "libsystemd0"
    "libudev1"
    "libwayland-client0"
    "libwayland-cursor0"
    "libwayland-server0"
    "libwlroots11"
    "libxcb1"
    "libxkbcommon0"

)
optdepends=(
	"alacritty: Terminal emulator used by the default config"
	"suckless-tools: Provides dmenu, an application launcher"
	"grim: Screenshot utility"
	"i3status: Status line"
	"mako-notifier: Lightweight notification daemon"
	"slurp: Select a region"
	"swayidle: Idle management daemon"
	"swaylock: Screen locker"
	"waybar: Highly customizable bar"
)
backup=(/etc/sway/config)
arch=("amd64")
url="https://github.com/WillPower3309/swayfx"
source=("${_pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/$pkgver.tar.gz"
	50-systemd-user.conf)
sha512sums=(
	"SKIP"
	"c2b7d808f4231f318e03789015624fd4cf32b81434b15406570b4e144c0defc54e216d881447e6fd9fc18d7da608cccb61c32e0e1fab2f1fe2750acf812d3137")
provides=("sway" "swayfx")
conflicts=("sway" "swayfx")
options=(debug)
install=sway.install

build() {
	meson \
		-Dsd-bus-provider=libsystemd \
		-Dwerror=false \
		"${_pkgname}-${pkgver}" build
	meson compile -C build
}

package() {
	install -Dm644 50-systemd-user.conf -t "$pkgdir/etc/sway/config.d/"

	DESTDIR="$pkgdir" meson install -C build

	cd "${_pkgname}-${pkgver}"
	install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
	for util in autoname-workspaces.py inactive-windows-transparency.py grimshot; do
		install -Dm755 "contrib/$util" -t "$pkgdir/usr/share/$pkgname/scripts"
	done
}