# Maintainer: exponential <echo ZXhwb25lbnRpYWxtYXRyaXhAcHJvdG9ubWFpbC5jb20K | base64 -d>
_pkgname=pytubefix
pkgname=python3-pytubefix
pkgver="8.8.3"
pkgrel=0
pkgdesc="Lightweight, Python library and cli for downloading YouTube videos, fork of pytube."
arch=('all')
license=('MIT')
depends=('python3')
makedepends=('python3-build' 'python3-installer' 'python3-wheel')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/JuanBindez/pytubefix/archive/refs/tags/v${pkgver}.tar.gz")
b2sums=('3570a20f5299456a777f011d31a6432ff8edba5a68f0c85d0631380c6d16cece6b78355961ecd0689bc33fc9e28a10412e24f5a60c6f6a5502aa969cc6a52498')

prepare(){
  cd "$srcdir/${_pkgname}-${pkgver}"
  # setuptools 67.4.0 is too high
  sed -i 's!setuptools>=67.4.0!setuptools>=0.0.0!' pyproject.toml
}

build(){
  cd "$srcdir/${_pkgname}-${pkgver}"
  python3 -m build --no-isolation --wheel
}

package() {
  cd $srcdir/${_pkgname}-${pkgver}
  python3 -m installer --destdir="$pkgdir" dist/*.whl #--optimize=1 --skip-build
  # Manual remove local
  mv "$pkgdir/usr/local/"* "$pkgdir/usr/"
  rmdir "$pkgdir/usr/local" 
  #doc
  install -Dm644 "README.md" "$pkgdir/usr/share/doc/$_pkgname/readme"
  install -Dm644 LICENSE "$pkgdir/usr/share/doc/$_pkgname/"
}