# Maintainer: exponential <echo ZXhwb25lbnRpYWxtYXRyaXhAcHJvdG9ubWFpbC5jb20K | base64 -d>
# Contributor: Stephen Zhang (AUR) <zsrkmyn at gmail dot com>
# Contributor: Jiachen Yang (AUR) <farseerfc@gmail.com>
# Contributor: lilydjwg (AUR) <lilydjwg@gmail.com>

pkgname=nvchecker
pkgver=2.16
pkgrel=0
pkgdesc="a tool for checking if a new version of some software has been released."
arch=('all')
url="https://github.com/lilydjwg/nvchecker"
license=('MIT')
depends=('python3' 'python3-structlog' 'python3-tornado' 'python3-pycurl' 'python3-platformdirs')
makedepends=('python3-build' 'python3-installer' 'python3-wheel' 'python3-setuptools')
optdepends=(
            #arch 'pyalpm: for "sort_version_key = vercmp" config'
            'python3-tomli: for Python < 3.11'
            'python3-awesomeversion: for "sort_version_key = awesomeversion" config'
            'python3-packaging: for "pypi" source'
            'python3-lxml: for "htmlparser" source'
            'python3-gi: for nvchecker-notify'
            'libnotify4: for nvchecker-notify')
source=("${pkgname}-$pkgver.tar.gz::https://github.com/lilydjwg/nvchecker/archive/refs/tags/v$pkgver.tar.gz")
b2sums=('a51600e3552ec27146e37b70f1cd292db6e3f0dddea545bec16aa3e09de1691d0a04f49e6ab8678c8b8ea550a173a02d16997684d4545300fe602c643e1214f8')

build() {
  cd $srcdir/${pkgname}-$pkgver
  python3 -m build --wheel --no-isolation
}

package() {
  cd $srcdir/${pkgname}-$pkgver
  python3 -m installer --destdir="$pkgdir" dist/*.whl #--optimize=1 --skip-build
  # Manual remove local
  mv "$pkgdir/usr/local/"* "$pkgdir/usr/"
  rmdir "$pkgdir/usr/local" 
  install -Dm644 sample_config.toml docs/usage.rst -t "$pkgdir/usr/share/doc/$pkgname/"
  install -Dm644 "LICENSE" "$pkgdir/usr/share/doc/$pkgname/license"
  install -Dm644 "README.rst" "$pkgdir/usr/share/doc/$pkgname/readme"
}

# vim:set ts=2 sw=2 et: