# Maintainer: hiddeninthesand <hiddeninthesand at protonmail dot com>

pkgname='melonds-git'
_gitname='melonds'
provides=('melonds')
pkgver=1.1.cce9de5
pkgrel=1
pkgdesc="DS emulator, sorta"
arch=('x86_64')
makedepends=('build-essential')
depends=('libcurl4-gnutls-dev' 'libpcap0.8-dev' 'libsdl2-dev' 'qt5-default' 'libslirp-dev' 'libarchive-dev' 'libepoxy-dev')
license=('GPL3')
url="https://github.com/Arisotura/${_gitname}"
conflicts=("${_gitname}" "${_gitname}-bin")

source=("git+${url}.git#tag=${pkgver}")
sha256sums=('SKIP')

pkgver() {
  cd "${_gitname}"
  printf "1.%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)" | sed 's|^v||'
}

build() {
    cd "${_gitname}"
    cmake -B build
    cmake --build build
}

package() {
    cd "${srcdir}"
    install -Dm755 "${_gitname}/build/melonDS" "${pkgdir}/usr/bin/melonDS"

    for size in 16 32 64 128 256; do
        install -Dm644 "${_gitname}/res/icon/melon_${size}x${size}.png" "${pkgdir}/usr/share/icons/hicolor/${size}x${size}/apps/melonDS.png"
    done
    sed "s/net.kuribo64.melonDS/melonDS/" -i "${_gitname}/res/net.kuribo64.melonDS.desktop"
    install -Dm644 "${_gitname}/res/net.kuribo64.melonDS.desktop" "${pkgdir}/usr/share/applications/melonDS.desktop"
}