# Maintainer: exponential <echo ZXhwb25lbnRpYWxtYXRyaXhAcHJvdG9ubWFpbC5jb20K | base64 -d>
# Contributor: schuay (AUR) <jakob.gruber@gmail.com>
# Contributor: Ray Powell (AUR) <ray_al@xphoniexx.net>
pkgname=mcomix
pkgver=3.1.0
pkgrel=0
pkgdesc="A user-friendly, customizable image viewer specifically designed to handle comic books"
arch=('all')
url="https://sourceforge.net/p/mcomix/wiki/Home/"
license=('GPL2')
depends=('python3' 'gir1.2-gtk-3.0' 'python3-pil' 'python3-gi' 'python3-cairo' 'python3-gi-cairo')
makedepends=('python3-build' 'python3-installer' 'python3-wheel')
optdepends=('libunrar5: for rar compressed comics'
            'p7zip: for 7z compressed comics'
            'unrar: for rar compressed comics'
            'unzip: for zip compressed comics'
            'lhasa: for lha compressed comics'
            'mupdf-tools: for PDF comics'
            'python3-chardet: character encoding detection')
source=("https://downloads.sourceforge.net/project/${pkgname}/MComix-${pkgver}/${pkgname}-${pkgver}.tar.gz")
b2sums=('9e5ca2a1735aaf77f4e46b926c36655e9e5fe19c37ce7583e88a71cc13978ee51ae7793ddef03d74829449f0960dcf42044a1ad41f59d1945d25c58d99b792fa')

build(){
  cd "${pkgname}-${pkgver}"
  python3 -m build --no-isolation --wheel
}

package() {
  cd "${pkgname}-${pkgver}"
  python3 -m installer --destdir="$pkgdir" dist/*.whl #--optimize=1 --skip-build
  # Manual remove local
  mv "$pkgdir/usr/local/"* "$pkgdir/usr/"
  rmdir "$pkgdir/usr/local" 
  # application meta files are no longer copied automatically by the installation process
  cp -a share "$pkgdir/usr"
  #doc
  install -Dm644 "README.md" "$pkgdir/usr/share/doc/$pkgname/readme"
  install -Dm644 "ChangeLog.md" "$pkgdir/usr/share/doc/$pkgname/changelog"
  ln -s /usr/share/common-licenses/GPL-2 "$pkgdir/usr/share/doc/$pkgname/"
  gzip "$pkgdir/usr/share/doc/$pkgname/changelog"
}