makedeb


libretro-beetle-psx 1.51ffd50-1


Sony PlayStation core

Viewing /PKGBUILD.

View raw.

Click here to go back to the Git tree for libretro-beetle-psx.

# Maintainer: Kay <lambdadeltacommunism@gmail.com>

pkgbase=libretro-beetle-psx
pkgname=(
  libretro-beetle-psx
  libretro-beetle-psx-hw
)
pkgver=1.51ffd50
pkgrel=1
pkgdesc='Sony PlayStation core'
arch=('amd64' 'arm64')
url=https://github.com/libretro/beetle-psx-libretro
license=(GPL2)
groups=(libretro)
depends=(
  libretro-core-info
  zlib1g
  libchdr0
)
makedepends=(
  git
  zlib1g-dev
  libchdr-dev
  libgl-dev
  libvulkan-dev
  libglvnd-dev
)
source=("${pkgname}::git+https://github.com/libretro/beetle-psx-libretro")
sha256sums=(SKIP)
options=(!lto)

pkgver() {
  cd "$pkgname"
  printf "%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}


prepare() {
  cp -r libretro-beetle-psx{,-hw}
}

build() {
  make \
    HAVE_LIGHTREC=1 \
    SYSTEM_LIBCHDR=1 \
    SYSTEM_ZLIB=1 \
    -C libretro-beetle-psx
  make \
    HAVE_HW=1 \
    HAVE_VULKAN=1 \
    HAVE_LIGHTREC=1 \
    SYSTEM_LIBCHDR=1 \
    SYSTEM_ZLIB=1 \
    -C libretro-beetle-psx-hw
}

package_libretro-beetle-psx() {
  export DEB_HOST_MULTIARCH=$(gcc -dumpmachine)
  install -Dm 644 libretro-beetle-psx/mednafen_psx_libretro.so -t "${pkgdir}"/usr/lib/$DEB_HOST_MULTIARCH/libretro/
}

package_libretro-beetle-psx-hw() {
  depends+=(libgl1 vulkan-icd libglvnd0)

  export DEB_HOST_MULTIARCH=$(gcc -dumpmachine)
  install -Dm 644 libretro-beetle-psx-hw/mednafen_psx_hw_libretro.so -t "${pkgdir}"/usr/lib/$DEB_HOST_MULTIARCH/libretro/
}


# vim: ts=2 sw=2 et: