# Maintainer: Matthias Mailänder <matthias@mailaender.name>

pkgname=languagetool
pkgver=6.5
pkgrel=1
pkgdesc='An open source language checker'
arch=(any)
url='https://www.languagetool.org'
license=(LGPL)
depends=(default-jre-headless)
makedepends=(unzip)
optdepends=('java-runtime: needed for the GUI version'
            'libxtst6-udeb: needed for the GUI version'
            'libgtk-3-0: GTK style for the GUI')
source=(https://www.languagetool.org/download/LanguageTool-$pkgver.zip
        languagetool.sh
        languagetool.service)
noextract=($pkgname-$pkgver.zip)
sha256sums=('27f3ae5a29efbc8267a5a266908dfec205d16d312af8516e0b5bcec871edea0b'
            'c559be1fbead8845caf1f269cf39bfde6486ce06aabcbdd4ba58d402168b61a7'
            '628e59208af02dd41c678135ef6dd8b328905701301d8257316b388d36d6c52b')

package() {
  install -d "$pkgdir"/usr/{bin,share/java/$pkgname/libs}
  unzip -q LanguageTool-$pkgver.zip -d "$pkgdir"/usr/share
  cd "$pkgdir"/usr/share/
  mv LanguageTool-${pkgver/.a/} $pkgname
  cd $pkgname
  mv *.jar "$pkgdir"/usr/share/java/$pkgname
  mv libs/*.jar "$pkgdir"/usr/share/java/$pkgname/libs
  rm -rf libs
  install -m755 "$srcdir"/$pkgname.sh "$pkgdir"/usr/bin/$pkgname
  mkdir -p "$pkgdir"/usr/lib/systemd/system
  install -m644 "$srcdir"/$pkgname.service "$pkgdir"/usr/lib/systemd/system/$pkgname.service
}