# Maintainer: SoftwareRat <jaguar5018@gmail.com>
# upstream patches:
# https://src.fedoraproject.org/cgit/rpms/gnome-terminal.git
# https://github.com/debarshiray/gnome-terminal

pkgname=gnome-terminal-transparency
_pkgname=gnome-terminal
pkgver=3.46.7
pkgrel=1
pkgdesc="The GNOME Terminal Emulator with background transparency"
url="https://wiki.gnome.org/Apps/Terminal"
arch=(amd64)
license=(GPL)
depends=(libvte-2.91-0 gsettings-desktop-schemas)
makedepends=(cmake gsettings-desktop-schemas-dev libnautilus-extension-dev libvte-2.91-dev docbook-xsl nautilus-extension-gnome-terminal gnome-shell yelp-tools meson)
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname" "$_pkgname-data")
groups=(gnome-extra)
changelog=package.changelog
options=(debug)
source=(https://gitlab.gnome.org/GNOME/$_pkgname/-/archive/$pkgver/$_pkgname-$pkgver.tar.gz
        transparency.patch)
sha256sums=('e4a57d33ebb179e3535e2255d0e2f6811d437a510a16298c62f8eba1e2293fad'
            '9d716c7b9a47f4da72a69dff3119793706a3e5e8a51b553fbe6f46fe548c2d88')

prepare() {
  cd $_pkgname-$pkgver
  patch -Np1 -i ../transparency.patch
}

build() {
  local meson_options=(
    -D b_lto=false
  )

  meson setup --prefix=/usr --buildtype=plain $_pkgname-$pkgver build "${meson_options[@]}"
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"
}