_gitname=geany
pkgname=${_gitname}
pkgver=3.80.1
pkgrel=1
pkgdesc="Fast and lightweight IDE (git version)"
arch=('amd64' 'arm64' 'armel' 'armhf'
'i386' 'mipsel' 'mips64el' 'ppc64el' 's390x')
url="https://github.com/${_gitname}/${_gitname}"
license=('GPL2')
depends=('libgtk-3-0' 'python3')

makedepends=('git' 'doxygen' 'intltool' 
'python3-lxml' 'python3-docutils' 'libgtk-3-dev' 
'python3-reportlab' 'libvted-3-dev' 'autopoint'
'autoconf' 'automake' 'libtool' 'pkg-config' 'm4')

optdepends=(
    'geany-plugins: additional functionality'
    'vte3: enbedded terminal support'
)
conflicts=("${_gitname}" "${_gitname}-gtk3" "${_gitname}-gtk3-git")
provides=("${_gitname}" "${_gitname}=$pkgver")
source=(${_gitname}::git+https://github.com/${_gitname}/${_gitname}.git)
md5sums=('SKIP')

prepare() {
  cd "${srcdir}/${_gitname}"

  # Syntax highlighting for PKGBUILD files
  sed -i 's/Sh=/Sh=PKGBUILD;/' data/filetype_extensions.conf
}

build() {
  cd "${srcdir}/${_gitname}"

  export CFLAGS="${CFLAGS} -D_FILE_OFFSET_BITS=64"
  ./autogen.sh \
    --enable-api-docs \
    --enable-html-docs \
    --enable-gtk3 \
    --enable-gtkdoc-header \
    --prefix=/usr
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd "${srcdir}/${_gitname}"

  make check
}

package() {
  cd "${srcdir}/${_gitname}"

  make PREFIX=/usr DESTDIR="$pkgdir" install
}