# Maintainer: Jonathan Apodaca <jrapodaca@gmail.com>
pkgname=fish
pkgver=4.0.1
pkgrel=2
epoch=1
conflicts=('fish-common')
depends=(
  'libtinfo6'
  'libatomic1'
  'libpcre2-32-0'
  'libstdc++6'
  'libc6'
  'libgcc1'
)
pkgdesc="The user-friendly command line shell."
arch=(amd64 arm64 arm32 i386 i686)
url="https://fishshell.com/"
license=('OpenBSD')
makedepends=(build-essential cmake gzip ncurses-term libpcre2-dev python3-sphinx gettext rsync)
source=(
  "https://github.com/fish-shell/fish-shell/releases/download/$pkgver/$pkgname-$pkgver.tar.xz"
)
sha256sums=('4ed63a70207283e15cf21fc5f21db4230421e4f98d4826b5b1c8254d69c762b5')

build() {
  cd "$pkgname-$pkgver"
  test ! -d build && mkdir build
  cd build
  cmake -DCMAKE_INSTALL_PREFIX="/usr" ..
  make
}

package() {
  pushd "$pkgname-$pkgver/build"
  make DESTDIR="$pkgdir" install
  popd

  pushd "$pkgname-$pkgver"
  mkdir -p "$pkgdir/usr/share/applications"
  mkdir -p "$pkgdir/usr/share/doc/fish"
  mkdir -p "$pkgdir/usr/share/fish/completions"
  install -D "etc/config.fish"    "$pkgdir/etc/fish/config.fish"
  rsync   -a "fish.desktop"       "$pkgdir/usr/share/applications/fish.desktop"
  rsync   -a "user_doc/html/"     "$pkgdir/usr/share/doc/fish/" --exclude "*.rst"
  rsync   -a "doc_src/"           "$pkgdir/usr/share/doc/fish/" --exclude "*.rst"
  rsync   -a "share/completions/" "$pkgdir/usr/share/fish/completions/"

  gzip "$pkgdir/usr/share/man/man1/fish.1"
  gzip "$pkgdir/usr/share/man/man1/fish_indent.1"
  gzip "$pkgdir/usr/share/man/man1/fish_key_reader.1"

}