# Maintainer: exponential <echo ZXhwb25lbnRpYWxtYXRyaXhAcHJvdG9ubWFpbC5jb20K | base64 -d>
# Contributor: Mark (AUR) <mark at sgtxd dot de >
pkgname='ani-cli-git'
_pkgname='ani-cli'
pkgver=4.5.0.r4.353bf56
pkgrel=1
pkgdesc="A cli to browse and watch anime. (development version)"
arch=('all')
url="https://github.com/pystardust/ani-cli"
license=('GPL3')
depends=('grep' 'sed' 'curl' 'mpv' 'aria2' 'ffmpeg' 'fzf')
optdepends=('vlc: An alternative video player'
            'rofi: Lightweight menu for X'
            'yt-dlp: Alternative m3u8 downloader')
makedepends=('git')
provides=('ani-cli')
conflicts=('ani-cli')
source=('ani-cli::git+https://github.com/pystardust/ani-cli.git')
b2sums=('SKIP')

pkgver() {
        cd "$srcdir/${_pkgname}"
        printf "%s.r%s.%s" "$(grep -m 1 'version_number' ani-cli | cut -d '"' -f 2)" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package() {
        cd "$srcdir/${_pkgname%-VCS}"
        install -Dm755 "ani-cli" "$pkgdir/usr/bin/ani-cli"
        install -Dm644 "LICENSE" "$pkgdir/usr/share/doc/$_pkgname/license"
        install -Dm644 "README.md" "$pkgdir/usr/share/doc/$_pkgname/readme"
        install -Dm644 "disclaimer.md" "$pkgdir/usr/share/doc/$_pkgname/disclaimer"
        install -Dm644 "$_pkgname.1" "$pkgdir/usr/share/man/man1/$_pkgname.1"
        gzip "$pkgdir/usr/share/man/man1/$_pkgname.1"
}