# Maintainer: exponential <echo ZXhwb25lbnRpYWxtYXRyaXhAcHJvdG9ubWFpbC5jb20K | base64 -d>
# Contributor: Alexander Jacocks (AUR) <alexander@redhat.com>
# Contributor: Frederic Bezies (AUR) <fredbezies at gmail dot com>
# Contributor: Benjamin Hodgetts (AUR) <ben@xnode.org>

pkgname=1oom
pkgver=1.0
pkgrel=0
pkgdesc="1oom is a Master of Orion (1993) game engine recreation."
arch=('amd64' 'i386')
url="https://gitlab.com/Tapani_/${pkgname}"
license=('GPL2')
makedepends=('libsdl2-dev' 'libsdl2-mixer-dev' 'libsamplerate0-dev')
depends=('libsdl2-2.0-0' 'libsdl2-mixer-2.0-0' 'libsamplerate0')
optdepends=('timgm6mb-soundfont: Soundfont, average but small'
            'fluid-soundfont-gm: Soundfont, good but big'
            'game-data-packager: Installer for game data files')
source=("${pkgname}-${pkgver}.tar.gz::${url}/-/archive/v${pkgver}/${pkgname}-v${pkgver}.tar.gz"
        "${pkgname}.png"
        "${pkgname}.desktop")
b2sums=('e54f5b803dd40110080da4b4c64964171cb2fc0fa60083cc0318f82c4ace0a5006e1c8e1e44b53c7f4acf1ee6287b861c373cba9dc7d9f32eaaf0a2cfa14a845'
        '9698161cc4a241d13f7c377b4417ae5807d02a0ee544929fac98d60d454f2c9784223e9764ad5ef568afc6b69af6cd9d729c4a59bbc4a7161bb30d053eb30390'
        '3e137452bec8de0af7e7dee85c5ade673dd02abf15b4c4255c266278dc57bb3243c1950922d2e10b37571552acf0253f936347a7fad56a542e2f20e1e70b9e83')

build() {
  cd "${pkgname}-v${pkgver}"
  autoreconf -fi
  test -d build-native || mkdir build-native
  cd build-native
  ../configure --prefix=/usr --bindir=/usr/games
  make -j "$(nproc)"
}

package() {
  cd "${srcdir}/${pkgname}-v${pkgver}"
  make PREFIX="/usr" DESTDIR="${pkgdir}" install -C "build-native"
  # install docs
  mkdir -p "$pkgdir/usr/share/doc/${pkgname}/instructions"
  install -Dm644 README "$pkgdir/usr/share/doc/${pkgname}/readme"
  cp doc/*.txt "$pkgdir/usr/share/doc/${pkgname}/instructions/"
  cp AUTHORS CODE_OF_CONDUCT COPYING HACKING NEWS PHILOSOPHY "$pkgdir/usr/share/doc/${pkgname}/"
  # Convenience symlink
  ln -s "/usr/games/1oom_classic_sdl2" "$pkgdir/usr/games/${pkgname}"
  # install icon and desktop file
  install -Dm644 "${srcdir}/${pkgname}.png" "$pkgdir/usr/share/icons/hicolor/96x96/apps/${pkgname}.png"
  install -Dm644 "${srcdir}/${pkgname}.desktop" "$pkgdir/usr/share/applications/${pkgname}.desktop"
}